前几天电脑安装了windows10,需要随时切换IP地址、IP网关之类，所以就在网上探索了教程，并修改为适合自己使用的。
1 代码部分
@echo off
rem //【附：该.bat命令只适合windows10系统，win7本人没有测试，代码源自互联网】下面一行命令是强制获取管理员权限
%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit
rem //设置变量
set NAME="以太网"
rem //以下属性值需要根据自己的实际情况更改，例如我的IP段是10.0.0.0/24
set ADDR=10.0.0.38
set MASK=255.0.0.0
set GATEWAY=10.0.0.10
set DNS1=10.0.0.10
set DNS2=
rem //以上属性依次为IP地址、子网掩码、网关、首选DNS、备用DNS
echo 当前可用操作有：
echo 1 设置为静态IP
echo 2 设置为动态IP
echo 3 退出
echo 请选择后回车：
set /p operate=
if %operate%==1 goto 1
if %operate%==2 goto 2
if %operate%==3 goto 3
:1
echo 正在设置静态IP，请稍等！
rem //可以根据你的需要更改
echo IP地址 = %ADDR%
echo 掩码 = %MASK%
echo 网关 = %GATEWAY%
netsh interface ipv4 set address %NAME% static %ADDR% %MASK% %GATEWAY%
echo 首选DNS = %DNS1%
netsh interface ipv4 set dns %NAME% static %DNS1% register=PRIMARY validate=no
echo 备用DNS = %DNS2%
if "%DNS2%"=="" (echo DNS2没有设置) else (netsh interface ipv4 add dns %NAME% %DNS2%)
echo 静态IP已设置！
pause
goto 3
:2
echo 正在设置动态IP，请稍等！
echo 正在从DHCP自动获取IP地址...
netsh interface ip set address %NAME% dhcp
echo 正在从DHCP自动获取DNS地址...
netsh interface ip set dns %NAME% dhcp
echo 动态IP已设置！
pause
goto 3
:3
exit2 文件编码
复制以上代码到 新建文本文档.txt 中
点击文件 –>> 另存为
文件名：自动配置IP地址.bat
保存类型：所有文件
编码:ANSI
3 配置网卡名
在脚本中需要根据自己电脑修改相应的网卡名配置
此处我的网卡名是 以太网
4 运行脚本
双击【自动配置IP地址.bat】，弹出【你要允许此应用对你的窗口进行更改吗？】提示，选择【是】后即可选择配置IP
End